Hi Bjarne,

Here's a way to do that:

<xsl:template match="/">
    <!-- Pick a random box index -->
    <xsl:variable name="random" select="floor(Exslt.ExsltMath:random() * count($boxIds)) + 1"/>

    <!-- Process the one - this gets us into the Umbraco XML doc -->
    <xsl:apply-templates select="$boxIds[position() = $random]" />
</xsl:template>

<!-- Simple 'redirect' to the referenced node -->
<xsl:template match="nodeId">
    <!-- id() works because we are now inside the Umbraco XML -->
    <xsl:apply-templates select="id(.)" />
</xsl:template>

<!-- Template for the Quote -->
<xsl:template match="Quote">
    <!-- Do something -->
</xsl:template>

The difference between id() and GetXmlNodeById() is that id() will return an empty set if the picked node has been deleted (it's also a native XPath function), where GetXmlNodeById() will return an error node (or something) that you will then need to error check.

The tricky part is that id() will only find a node inside the document that contains the current context node - a concept that's also hard to explain in Umbraco's specific environment - I tried here: https://gist.github.com/871656

So by applying templates for the randomly selected <nodeId> element, we get "into" the Umbraco XML and from there can just use the id() function and not worry about error messages for deleted nodes.

I know it's a completely different way of thinking, in terms of what most people are used to, but using XSLT it just makes so much more sense.

/Chriztian

Hi Chriztian

Thanks, it seems to do it :)

I have done something similar before, but where I just get a random node of a nodeset.

<xsl:param name="currentPage"/>
        <xsl:variable name="random" select="floor(emath:random() * count($currentPage/ancestor-or-self::root/descendant-or-self::Quote)) + 1"/>

        <xsl:template match="/">
         <xsl:apply-templates select="$currentPage/ancestor-or-self::root/descendant-or-self::Quote[$random]" />
        </xsl:template>

        <xsl:template match="Quote">
                <div id="randquote">
                        <xsl:apply-templates select="quoteText[normalize-space()]" />
                        <xsl:apply-templates select="quoteName[normalize-space()]" />
                </div>
        </xsl:template>
        
        <xsl:template match="quoteText">
                <p class="quoteText">
                        <xsl:value-of select="." />
                  <span class="quote_end"><xsl:text> </xsl:text></span>
                </p>
                
        </xsl:template>
          
        <xsl:template match="quoteName">
                <p class="name">
                        <xsl:value-of select="." />
                </p>
        </xsl:template>

So what you get from the code above is a random node id and from that get the xml?

This is the code I ended up with:

<xsl:param name="currentPage"/>
  <xsl:variable name="boxIds" select="$currentPage/self::*[normalize-space(boxes)][1]/boxes//nodeId" />
  <!-- Replace 'article' with the wanted document -->
  <xsl:variable name="random" select="floor(Exslt.ExsltMath:random() * count($boxIds)) + 1"/>

  <xsl:template match="/">
      <!-- Pick a random box index -->
      <xsl:variable name="random" select="floor(Exslt.ExsltMath:random() * count($boxIds)) + 1"/>

      <!-- Process the one - this gets us into the Umbraco XML doc -->
      <xsl:apply-templates select="$boxIds[position() = $random]" />
  </xsl:template>

  <!-- Simple 'redirect' to the referenced node -->
  <xsl:template match="nodeId">
        <!-- id() works because we are now inside the Umbraco XML -->
        <xsl:apply-templates select="id(.)" />
  </xsl:template>

  <xsl:template match="Quote">
      <xsl:variable name="qSize" select="quoteTextSize" />
      <xsl:variable name="textSize">
        <xsl:value-of select="Exslt.ExsltStrings:lowercase($qSize)"/>
      </xsl:variable>

      <xsl:variable name="qClass">
      <xsl:choose>
        <xsl:when test="$textSize = 'small' or $textSize = ''">
            <xsl:value-of select="'smallText'"/>
        </xsl:when>
        <xsl:when test="$textSize = 'medium'">
            <xsl:value-of select="'mediumText'"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="'largeText'"/>
        </xsl:otherwise>
      </xsl:choose>
      </xsl:variable>

      <section>
            <xsl:attribute name="class">
                <xsl:text>quoteBox </xsl:text>
                <xsl:value-of select="$qClass"/>
            </xsl:attribute>
            <p class="quoteText">
                <xsl:if test="quoteText != ''">
                    <xsl:value-of select="concat('&quot;', umbraco.library:ReplaceLineBreaks(quoteText), '&quot;')" disable-output-escaping="yes"/>
                </xsl:if>
            </p>
            <p class="quoteName"><xsl:value-of select="umbraco.library:ReplaceLineBreaks(quoteName)" disable-output-escaping="yes"/></p>
      </section>

  </xsl:template>

/Bjarne

is working on a reply...